//INCLUDE DIRECTIVES
//peasycam is a camera library available at http://mrfeinberg.com/peasycam/
import peasy.*;

//GLOBAL VARIABLES
int imgWidth = 193;
int imgHeight = 220;

//pixel arrays
int[][] pixel = new int[imgWidth][imgHeight];
int[][] rVal = new int[imgWidth][imgHeight];
int[][] gVal = new int[imgWidth][imgHeight];
int[][] bVal = new int[imgWidth][imgHeight];

//image variable
PImage img;

//camera
PeasyCam cam;

//The SETUP method is called once when the applet/application starts off. 
//Consider this a 'point or method of entry'
void setup()
{
  //size method declares the size of the applet window and to use the 3d 
  //libraries (P3D or OPENGL it must be declared in this size method
  size(400,400,P3D);
  
  img = loadImage("me.jpg");                             //load the image
  image(img,0,0);                                        //draw the image at 0,0

  cam = new PeasyCam(this,350);                          //declare the camera
  cam.lookAt(width/2+30, height/2,0);
  cam.rotateY(0.05);

  for(int i = 0; i<imgWidth; i=i+1) {                    //read the pixel information
    for(int j = 0; j<imgHeight; j=j+1){
      pixel[i][j] = img.pixels[j*imgWidth + i];
      rVal[i][j] = int(red(pixel[i][j]));
      gVal[i][j] = int(green(pixel[i][j]));
      bVal[i][j] = int(blue(pixel[i][j]));
    }
  }
}

//the DRAW Method is called continuously (at a certain framerate). Consider this a continous LOOP
void draw()
{
  background(255);                                       //cleans up applet window and fills it with a color
      
  for(int i = 0; i<imgWidth; i=i+1) {                    //draw lines of different heights based on the pixel information
    for(int j = 0; j<imgHeight; j=j+1){
      stroke(rVal[i][j],gVal[i][j],bVal[i][j]);
      line(i + width/2 - imgWidth/2,j + height/2 - imgHeight/2,-100,i + width/2 - imgWidth/2,j+ height/2 - imgHeight/2,bVal[i][j]/2-100);
    }
  } 
}